@echo off
setlocal
title Installazione RustDesk - Soltea

set "RD_CFG=9JSPzlEUI5GM4IFayJXduZ3SpNET2dmb1YmSEdTUsdDaPJHU3VWap9Wd1lzbRJiOikXZrJCLiIiOikGchJCLiQXauEWZ0x2bz5SOxYnczJiOikXYsVmciwiI0lmLhVGds92cukTM2J3ciojI0N3boJye"
set "RD_URL=https://repository.soltea.it/rustdesk/rustdesk-1.4.9-x86_64.exe"
set "RD_DIR=C:\Program Files\RustDesk"

net session >nul 2>&1
if errorlevel 1 (
  echo Questo script deve essere eseguito come AMMINISTRATORE.
  echo Chiudi, fai clic destro sul file e scegli "Esegui come amministratore".
  echo.
  pause
  exit /b 1
)

cd /d "%TEMP%"
if exist "%~dp0rustdesk-1.4.9-x86_64.exe" (
  copy /y "%~dp0rustdesk-1.4.9-x86_64.exe" rustdesk.exe >nul
) else (
  echo Scarico RustDesk...
  curl -L -o rustdesk.exe "%RD_URL%" || (echo Download fallito. & pause & exit /b 1)
)

echo Installazione in corso (puo' richiedere qualche minuto)...
start "" rustdesk.exe --silent-install

rem L'installer non termina da solo: attendo la comparsa dell'eseguibile, max 3 minuti.
set /a RD_TRY=0
:waitloop
if exist "%RD_DIR%\rustdesk.exe" goto installed
timeout /t 3 /nobreak >nul
set /a RD_TRY+=1
if %RD_TRY% lss 60 goto waitloop
echo Installazione non riuscita: "%RD_DIR%\rustdesk.exe" non trovato.
pause
exit /b 1

:installed
timeout /t 10 /nobreak >nul
cd /d "%RD_DIR%"
rustdesk.exe --install-service
timeout /t 10 /nobreak >nul

echo Applico la configurazione del server Soltea...
rustdesk.exe --config %RD_CFG%
timeout /t 3 /nobreak >nul

for /f "delims=" %%i in ('rustdesk.exe --get-id ^| more') do set "RD_ID=%%i"

echo.
echo ===============================================
echo  RustDesk installato e configurato.
echo  Il tuo ID e': %RD_ID%
echo  Comunicalo all'assistenza Soltea insieme alla
echo  password monouso che vedi nella finestra di RustDesk.
echo ===============================================
echo.
pause
endlocal